Adding code coverage

Makefile.am

@@ -4,3 +4,21 @@ EXTRA_DIST = README.md \
 	NEWS
 
 ACLOCAL_AMFLAGS = -I m4
+
+.PHONY: lcov genlcov lcov-clean
+
+lcov:
+	-$(MAKE) $(AM_MAKEFLAGS) -k check
+	$(MAKE) $(AM_MAKEFLAGS) genlcov
+
+# we have to massage the lcov.info file slightly to hide the effect of libtool
+# placing the objects files in the .libs/ directory separate from the *.c
+genlcov:
+	$(LTP) --directory $(top_builddir) --capture --output-file miraclecast-lcov.info --test-name GLIB_PERF --no-checksum
+	LANG=C $(LTP_GENHTML) --prefix $(top_builddir) --output-directory miraclecast-lcov --title "Miraclecast Code Coverage" --legend --show-details miraclecast-lcov.info
+
+lcov-clean:
+	-$(LTP) --directory $(top_builddir) -z
+	-rm -rf miraclecast-lcov.info miraclecast-lcov
+	-find -name '*.gcda' -print | xargs -Ix rm x
+

README.md

@@ -2,6 +2,7 @@
 
 [![Join the chat at https://gitter.im/albfan/miraclecast](https://badges.gitter.im/albfan/miraclecast.svg)](https://gitter.im/albfan/miraclecast?utm_source=badge&utm_medium=badge&utm_campaign=pr-badge&utm_content=badge)
 [![Build Status](https://semaphoreci.com/api/v1/projects/5ece4a7a-365b-4f7c-bfcc-6dcdece7002f/671892/badge.svg)](https://semaphoreci.com/albfan/miraclecast)
+[![Coverage Status](https://coveralls.io/repos/github/albfan/miraclecast/badge.svg?branch=master)](https://coveralls.io/github/albfan/miraclecast?branch=master)
 
 The MiracleCast project provides software to connect external monitors to your system via Wi-Fi. It is compatible to the Wifi-Display specification also known as Miracast. MiracleCast implements the Display-Source as well as Display-Sink side.
 

configure.ac

@@ -59,6 +59,78 @@ PKG_CHECK_MODULES([CHECK], [check],
                   [have_check=yes], [have_check=no])
 AM_CONDITIONAL([BUILD_HAVE_CHECK], [test "x$have_check" = "xyes"])
 
+if test "x$have_check" = "xyes"
+then
+
+  dnl ************************************
+  dnl *** Enable lcov coverage reports ***
+  dnl ************************************
+  
+  AC_ARG_ENABLE(gcov,
+    AS_HELP_STRING([--enable-gcov],
+  		 [Enable gcov]),
+    [use_gcov=$enableval], [use_gcov=no])
+  
+  if test "x$use_gcov" = "xyes"; then
+    dnl we need gcc:
+    if test "$GCC" != "yes"; then
+      AC_MSG_ERROR([GCC is required for --enable-gcov])
+    fi
+  
+    dnl Check if ccache is being used
+    AC_CHECK_PROG(SHTOOL, shtool, shtool)
+    case `$SHTOOL path $CC` in
+      *ccache*[)] gcc_ccache=yes;;
+      *[)] gcc_ccache=no;;
+    esac
+  
+    if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
+      AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
+    fi
+  
+    ltp_version_list="1.6 1.7 1.8 1.11 1.12"
+    AC_CHECK_PROG(LTP, lcov, lcov)
+    AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
+  
+    if test "$LTP"; then
+      AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
+        glib_cv_ltp_version=invalid
+        ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
+        for ltp_check_version in $ltp_version_list; do
+          if test "$ltp_version" = "$ltp_check_version"; then
+            glib_cv_ltp_version="$ltp_check_version (ok)"
+          fi
+        done
+      ])
+    else
+      ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
+      AC_MSG_ERROR([$ltp_msg])
+    fi
+  
+    case $glib_cv_ltp_version in
+      ""|invalid[)]
+        ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
+        AC_MSG_ERROR([$ltp_msg])
+        LTP="exit 0;"
+        ;;
+    esac
+  
+    if test -z "$LTP_GENHTML"; then
+      AC_MSG_ERROR([Could not find genhtml from the LTP package])
+    fi
+  
+    AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
+  
+    dnl Remove all optimization flags from CFLAGS
+    changequote({,})
+    CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
+    changequote([,])
+  
+    dnl Add the special gcc flags
+    CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
+    LDFLAGS="$LDFLAGS -lgcov"
+  fi
+fi
 #
 # Makefile vars
 # After everything is configured, we create all makefiles.
@@ -92,6 +164,7 @@ AC_MSG_NOTICE([Build configuration:
 
 Miscellaneous Options:
        building tests: $have_check
+       code coverage: $use_gcov
 
 Compilation
        mkdir build && cd build