mirror of
https://github.com/ton-blockchain/ton
synced 2025-03-09 15:40:10 +00:00
85 lines
3.6 KiB
Text
85 lines
3.6 KiB
Text
#!/usr/bin/fift -s
|
|
"TonUtil.fif" include
|
|
"GetOpt.fif" include
|
|
|
|
{ show-options-help 1 halt } : usage
|
|
|
|
"" =: comment // comment for simple transfers
|
|
true =: allow-bounce
|
|
false =: force-bounce
|
|
3 =: send-mode // mode for SENDRAWMSG: +1 - sender pays fees, +2 - ignore errors
|
|
60 =: timeout // external message expires in 60 seconds
|
|
variable extra-currencies
|
|
{ extra-currencies @ cc+ extra-currencies ! } : extra-cc+!
|
|
|
|
begin-options
|
|
" <filename-base> <dest-addr> <subwallet-id> <seqno> <amount> [-x <extra-amount>*<extra-currency-id>] [-n|-b] [-t<timeout>] [-B <body-boc>] [-C <comment>] [-I <init-boc>] [<savefile>]" +cr +tab
|
|
+"Creates a request to advanced wallet created by new-wallet-v3.fif, with private key loaded from file <filename-base>.pk "
|
|
+"and address from <filename-base>.addr, and saves it into <savefile>.boc ('wallet-query.boc' by default)"
|
|
disable-digit-options generic-help-setopt
|
|
"n" "--no-bounce" { false =: allow-bounce } short-long-option
|
|
"Clears bounce flag" option-help
|
|
"b" "--force-bounce" { true =: force-bounce } short-long-option
|
|
"Forces bounce flag" option-help
|
|
"x" "--extra" { $>xcc extra-cc+! } short-long-option-arg
|
|
"Indicates the amount of extra currencies to be transfered" option-help
|
|
"t" "--timeout" { parse-int =: timeout } short-long-option-arg
|
|
"Sets expiration timeout in seconds (" timeout (.) $+ +" by default)" option-help
|
|
"B" "--body" { =: body-boc-file } short-long-option-arg
|
|
"Sets the payload of the transfer message" option-help
|
|
"C" "--comment" { =: comment } short-long-option-arg
|
|
"Sets the comment to be sent in the transfer message" option-help
|
|
"I" "--with-init" { =: init-file } short-long-option-arg
|
|
"Indicates filename with BoC containing StateInit for internal message" option-help
|
|
"m" "--mode" { parse-int =: send-mode } short-long-option-arg
|
|
"Sets transfer mode (0..255) for SENDRAWMSG (" send-mode (.) $+ +" by default)"
|
|
option-help
|
|
"h" "--help" { usage } short-long-option
|
|
"Shows a help message" option-help
|
|
parse-options
|
|
|
|
$# dup 5 < swap 6 > or ' usage if
|
|
6 :$1..n
|
|
|
|
true constant bounce
|
|
$1 =: file-base
|
|
$2 bounce parse-load-address force-bounce or allow-bounce and =: bounce 2=: dest_addr
|
|
$3 parse-int =: subwallet_id
|
|
$4 parse-int =: seqno
|
|
$5 $>cc extra-cc+! extra-currencies @ 2=: amount
|
|
$6 "wallet-query" replace-if-null =: savefile
|
|
subwallet_id (.) 1 ' $+ does : +subwallet
|
|
|
|
file-base +subwallet +".addr" dup file-exists? { drop file-base +".addr" } ifnot
|
|
load-address
|
|
2dup 2constant wallet_addr
|
|
."Source wallet address = " 2dup .addr cr 6 .Addr cr
|
|
file-base +".pk" load-keypair nip constant wallet_pk
|
|
|
|
def? body-boc-file { @' body-boc-file file>B B>boc } { comment simple-transfer-body } cond
|
|
constant body-cell
|
|
|
|
def? init-file { @' init-file file>B B>boc <s b{11} swap |_ } { b{0} } cond
|
|
=: state-init
|
|
|
|
."Transferring " amount .GR+cc ."to account "
|
|
dest_addr 2dup bounce 7 + .Addr ." = " .addr
|
|
."subwallet_id=0x" subwallet_id x.
|
|
."seqno=0x" seqno x. ."bounce=" bounce . cr
|
|
."Body of transfer message is " body-cell <s csr. cr
|
|
."StateInit is " state-init csr. cr
|
|
|
|
// create a message
|
|
<b b{01} s, bounce 1 i, b{000} s, dest_addr Addr, amount Gram+cc, 0 8 64 32 + + u, state-init s,
|
|
body-cell <s 2dup 1 s-fits-with? not rot over 1 i, -rot { drop body-cell ref, } { s, } cond
|
|
b>
|
|
<b subwallet_id 32 u, now timeout + 32 u, seqno 32 u, send-mode 8 u, swap ref, b>
|
|
dup ."signing message: " <s csr. cr
|
|
dup hashu wallet_pk ed25519_sign_uint
|
|
<b b{1000100} s, wallet_addr addr, 0 Gram, b{00} s,
|
|
swap B, swap <s s, b>
|
|
dup ."resulting external message: " <s csr. cr
|
|
2 boc+>B dup Bx. cr
|
|
savefile +".boc" tuck B>file
|
|
."Query expires in " timeout . ."seconds" cr
|
|
."(Saved to file " type .")" cr
|